File:Catch quality chances (with scaling).svg

set terminal svg size 400 300
set samples 1001
set xlabel "1.4 Fishing Power"
set ylabel "Chance"
set format y "%g%%"
set key inside right top Right vertical opaque box
set object 1 rectangle from screen 0,0 to screen 1,1 fc rgb "white" behind

# scaling
f(x) = x > 50 ? floor(50 + (x - 50) * .95) : x
g(x) = f(x) > 75 ? floor(75 + (f(x) - 75) * .9) : f(x)
h(x) = g(x) > 100 ? floor(100 + (g(x) - 100) * .85) : g(x)
i(x) = h(x) > 125 ? floor(125 + (h(x) - 125) * .8) : h(x)
j(x) = i(x) > 150 ? floor(150 + (i(x) - 150) * .75) : i(x)
k(x) = j(x) > 175 ? floor(175 + (j(x) - 175) * .7) : j(x)
efp(x) = k(x) > 200 ? floor(200 + (k(x) - 200) * .65) : k(x)

max(a,b) = (a > b) ? a : b
common(x) = 100.0 / max(floor(150 / efp(x)), 2)
uncommon(x) = 100.0 / max(floor(150 * 2 / efp(x)), 3)
rare(x) = 100.0 / max(floor(150 * 7 / efp(x)), 4)
veryrare(x) = 100.0 / max(floor(150 * 15 / efp(x)), 5)
exrare(x) = 100.0 / max(floor(150 * 30 / efp(x)), 6)

plot [0:424] [0:55] \
	common(x) title 'Common' with steps, \
	uncommon(x) title 'Uncommon' with steps, \
	rare(x) title 'Rare' with steps, \
	veryrare(x) title 'Very Rare' with steps, \
	exrare(x) title 'Extremely Rare' with steps